7.2.32 LinkingAboveStartEnd principle

• identifier: principle.linkingAboveStartEnd
• dimension variables: D1, D2, D3
• argument variables:
  Start: vec(label(D1) set(label(D2)))
End: vec(label(D1) set(label(D2)))
• default values:
  Start: ^.D3.entry.start
End: ^.D3.entry.end
• model record: empty
• constraints: LinkingAboveStartEnd (priority 100)
• edge constraints: none

This principle assumes that the Graph principle (Graph) is used on dimensions D1 and D2.¹

This principle is from the family of linking principles. For all edges from v to v' labeled l on D1, it stipulates the constraints:

• if Start(l) is not empty, then on D2, v' must be above an edge into v labeled by a label in Start(l)
• if End(l) is not empty, then on D2, v' must be above v, and the outgoing edge of v' must be in End(l)

Here is the definition of the LinkingAboveStartEnd constraint functor:

%% Copyright 2001-2008
%% by Ralph Debusmann <rade@ps.uni-sb.de> (Saarland University) and
%%    Denys Duchier <duchier@ps.uni-sb.de> (LIFO, Orleans) and
%%    Jorge Marques Pelizzoni <jpeliz@icmc.usp.br> (ICMC, Sao Paulo) and
%%    Jochen Setz <info@jochensetz.de> (Saarland University)
%%
functor
import
%   System(show)

   Helpers(checkModel) at 'Helpers.ozf'
   Opti(isIn) at 'Opti.ozf'
export
   Constraint
define
   proc {Constraint Nodes G Principle FD FS Select}
      DVA2DIDA = Principle.dVA2DIDA
      ArgRecProc = Principle.argRecProc
      %%
      D1DIDA = {DVA2DIDA 'D1'}
      D2DIDA = {DVA2DIDA 'D2'}
      DIDA2LabelLat = G.dIDA2LabelLat
      D1LabelLat = {DIDA2LabelLat D1DIDA}
      D2LabelLat = {DIDA2LabelLat D2DIDA}
      D1LAs = D1LabelLat.constants
      D2LAs = D2LabelLat.constants
   in
      if {Helpers.checkModel 'LinkingAboveStartEnd.oz' Nodes
	  [D1DIDA#daughtersL
	   D2DIDA#upL
	   D2DIDA#downL]} then
	 for Node1 in Nodes do
	    for Node2 in Nodes do
	       for LA in D1LAs do
		  if {Not {Opti.isIn Node2.index Node1.D1DIDA.model.daughtersL.LA}=='out'} then
	 
		     local
			%% Linking Above and Startpoint
			%% m -l->1 d =>
			%%   Start(l) neq emptyset =>
			%%     d ->*2 -Start(l)->2 m
			StartLALMRec =
			{ArgRecProc 'Start' o('^': Node1)}
			StartLM = StartLALMRec.LA
			%%
			Node1D2UpLMs =
			{Map D2LAs
			 fun {$ LA} Node1.D2DIDA.model.upL.LA end}
			Node1D2UpLM =
			{Select.union Node1D2UpLMs StartLM}
		     in
			{FD.impl
			 {FS.reified.include Node2.index Node1.D1DIDA.model.daughtersL.LA}
			 {FD.impl
			  {FD.nega {FS.reified.equal StartLM FS.value.empty}}
			  {FS.reified.include Node2.index Node1D2UpLM}} 1}
		     end
		     %%
		     local
			%% Linking Above and Endpoint
			%% m -l->1 d =>
			%%   End(l) neq emptyset =>
			%%     d -End(l)->2 ->*2 m
			EndLALMRec =
			{ArgRecProc 'End' o('^': Node1)}
			EndLM = EndLALMRec.LA
			%%
			Node2D2DownLMs =
			{Map D2LAs
			 fun {$ LA} Node2.D2DIDA.model.downL.LA end}
			Node2D2DownLM =
			{Select.union Node2D2DownLMs EndLM}
		     in
			{FD.impl
			 {FS.reified.include Node2.index Node1.D1DIDA.model.daughtersL.LA}
			 {FD.impl
			  {FD.nega {FS.reified.equal EndLM FS.value.empty}}
			  {FS.reified.include Node1.index Node2D2DownLM}} 1}
		     end
		  end
	       end
	    end
	 end
      end
   end
end