Lvc.Infra.AutoIndTac

Ltac revert_except E :=
  repeat match goal with
           [H : _ |- _] ⇒
           match H with
             | E ⇒ fail 1
             | _ ⇒ revert H
               end
         end.

Ltac clear_except E :=
  repeat match goal with
           [H : _ |- _] ⇒
           match H with
             | E ⇒ fail
             | _ ⇒ clear H
               end
         end.

Ltac clear_all :=
  repeat match goal with
           [H : _ |- _] ⇒ clear H
         end.

Ltac revert_all :=
  repeat match goal with
           [H : _ |- _] ⇒ revert H
         end.


Class DoNotRemember (T:Type) := DNR { Q:Type }.

Declare ML Module "lvc_plugin".

Ltac remember_arguments E :=
  let tac t x := ( try (is_param t 0; fail 1);
                  try (is_var x; fail 1);
                  try (assert (DoNotRemember x) by eauto with typeclass_instances; fail 1 );
                  remember (x))
  in
  repeat (match type of E with
    | ?t ?x _ _ _ _ _ _ _ _ _ _ _ _ _ _ _ ⇒ tac t x
    | ?t ?x _ _ _ _ _ _ _ _ _ _ _ _ _ _ ⇒ tac t x
    | ?t ?x _ _ _ _ _ _ _ _ _ _ _ _ _ ⇒ tac t x
    | ?t ?x _ _ _ _ _ _ _ _ _ _ _ _ ⇒ tac t x
    | ?t ?x _ _ _ _ _ _ _ _ _ _ _ ⇒ tac t x
    | ?t ?x _ _ _ _ _ _ _ _ _ _ ⇒ tac t x
    | ?t ?x _ _ _ _ _ _ _ _ _ ⇒ tac t x
    | ?t ?x _ _ _ _ _ _ _ _ ⇒ tac t x
    | ?t ?x _ _ _ _ _ _ _ ⇒ tac t x
    | ?t ?x _ _ _ _ _ _ ⇒ tac t x
    | ?t ?x _ _ _ _ _ ⇒ tac t x
    | ?t ?x _ _ _ _ ⇒ tac t x
    | ?t ?x _ _ _ ⇒ tac t x
    | ?t ?x _ _ ⇒ tac t x
    | ?t ?x _ ⇒ tac t x
    | ?t ?x ⇒ tac t x
  end).

Ltac clear_dup :=

  match goal with
  | [ H : ?X |- _ ] ⇒
    match goal with
    | [ H' : ?Y |- _ ] ⇒
      match H with
      | H' ⇒ fail 2
      | _ ⇒ unify X Y ; (clear H' || clear H)
      end
    end
  end.

Ltac clear_if_dup H :=
  match type of H with
    | ?X ⇒
      match goal with
      | [ H' : ?Y |- _ ] ⇒
        match H with
        | H' ⇒ fail 2
        | _ ⇒ unify X Y ; (clear H' || clear H)
        end
      end
  end.

Ltac inv_eqs :=
  repeat (match goal with
              | [ H : @eq _ ?x ?x |- _ ] ⇒ clear H
              | [ H : @eq _ ?x ?y |- _ ] ⇒ progress (inversion H; subst; try clear_dup)
            end).

Ltac clear_trivial_eqs :=
  repeat (progress (match goal with
                    | [ H : @eq _ ?x ?x |- _ ] ⇒ clear H
                    | [ H : @eq _ ?x ?y |- _ ] ⇒ first [ is_var x; subst x | is_var y; subst y ]
                    | [ H : true = false |- _ ] ⇒ exfalso; inversion H
                    | [ H : @eq _ (Some ?x) (Some ?y) |- _ ]
                      ⇒ let H' := fresh "H" in assert (H':x = y) by congruence; clear H;
                                              first [ is_var x; subst x; clear H'
                                                    | is_var y; subst y; clear H'
                                                    | rename H' into H ]
                    end)).

Tactic Notation "general" "induction" hyp(H) :=
  remember_arguments H; revert_except H;
  induction H; intros; (try inv_eqs); (try clear_trivial_eqs).

Tactic Notation "indros" :=
  intros; (try inv_eqs); (try clear_trivial_eqs).

Module Test.

  Require Import List.

  Inductive decreasing : list nat → Prop :=
  | base : decreasing nil
  | step m n L : decreasing (n::L) → n ≤ m → decreasing (m :: n :: L).

  Lemma all_zero_by_hand L
    : decreasing (0::L) → ∀ x, In x L → x = 0.
  Proof.
    intros. remember (0::L).
    revert dependent L. revert x. induction H; intros.
    inversion Heql.
    inversion Heql. subst. inversion H0; subst; firstorder.
  Qed.

  Lemma all_zero L
    : decreasing (0::L) → ∀ x, In x L → x = 0.
  Proof.
    intros. general induction H.
    inversion H0; subst; firstorder.
  Qed.

End Test.